电子发烧友App
这个时间服务器应用程序的另一个子模块为web服务器。此应用程序中的HTTP服务器实现了一个RFC 2068中描述的HTTP服务器简易版本。在我们的版本中，仅支持GET方法，忽略输入头文件，并且几乎不给出输出包头。在撰写这篇应用笔记时尚未提供文件系统库，因此示例应用程序动态地生成HTML网页。
通过调用Berkley-style socket函数来创建服务器socket。这使得建立一个服务器socket十分容易。以下代码给出我们的简易HTTP服务器的创建、绑定和接受新连接。
struct sockaddr local;
unsigned int socket_handle, new_socket_handle, temp;
socket_handle = socket(0, SOCKET_TYPE_STREAM, 0);
local.sin_port = htons(80);
bind(socket_handle, &local, sizeof(local));
listen(socket_handle, 5);
printf("Ready to accept HTTP connections...\r
");
// here is the main loop of the HTTP server
while (1)
{
new_socket_handle = accept(socket_handle, &address, sizeof(address));
handleRequest(new_socket_handle);
closesocket(new_socket_handle);
}
注意当接收到一个新的socket时，这一简易应用程序不会启动一个新的线程或进程处理该请求，而是在同一进程中处理请求。任何优于该演示的HTTP服务器都会在一个新的线程中处理到来的请求，允许同时发生多个连接并能进行处理。请求处理完毕后我们关闭socket并等待下一个到来的连接。
handleRequest方法从接入的请求中解析出文件名并且验证请求方法为GET。不允许使用其它方法(即使是POST、HEAD或OPTIONS)。
为IAR编译器编写DS80C400汇编函数的注意事项
IAR文档提供了在8051汇编中编写程序，可从C程序中调用的方法。若8051汇编函数由IAR编译器编写的C程序来调用，在编写这些汇编语言时需切记以下几点。如果没有可用的寄存器传递变量时，会将这些变量以Little Endian顺序压入堆栈。
函数参变量传递约定
下表说明了变量的传递方式。ArgumentsCharacter
8-bit valuesR1,R2,R3,R4,R5
16-bit valuesR3:R2 or R5:R4
24-bit (pointer) valuesR3:R2:R1
32-bit valuesR5:R4:R3:R2
下表显示了函数返回值的规则。ArgumentsCharacter
8-bit valuesR1
16-bit valuesR3:R2
24-bit (pointer) valuesR3:R2:R1
32-bit valuesR5:R4:R3:R2
函数int foo(int x, int y,void* ptr);的变量和返回值的传递如下：
数据类型存储规则
IAR遵循Little Endian存储规则。注意，IAR使用最低有效字节在前的二进制数据存储格式。
例如，一个4字节长的数值0xDEADBEEF，将会按如下方式存储：
一个简单的汇编程序与'C'接口
本节演示如何编写一个汇编程序并用IAR Embedded Workbench与'C'程序接口。应用程序交换16位和32位字节，并将交换后的字节输出到默认的控制台。C的可调用函数原型是int ltob( int *shortptr , long *longptr)。
本示例程序由两个文件组成：main.c和eswap.s51。main.c调用我们用汇编语言编写的示例函数ltob()。创建一个新项目，命名为endian;添加cstartup.s51、low_level_init.s51、putchar.c文件以及Dallas Semiconductor ROM初始化库rominit.r51。详细资料请参考上述从8051 IAR Embedded Workbench开始。
用以下内容来创建一个新的main.c文件，并将该文件添加到项目endian中。在C中，必须声明一个函数，以便让编译器知道如何调用它。ltob()函数在main()之前声明。注意在成功运行后函数ltob()会返回'0'，而且，如果任一指针为NULL则返回非零值。程序应向控制台输出以下结果：
--------------------------------------------------------------------------------------------------------------------
Program output:
Set values: int= 0xdead long = 0x12345678
Converted values: int= 0xedde long = 0x78563412
-------------------------------------------------------------------------------------------------------------------
// program main.c
#include
#include
#include
int ltob(unsigned int *intptr,unsigned long *longptr);
void main()
{
unsigned long i = 0x12345678;
unsigned int k = 0xdead;
int err;
printf("set values: int=0x%x long=0x%lx
",k,i);
err = ltob(&k,&i);
if(err)
printf("Error: One of the pointers is NULL
");
else
printf("converted values: int=0x%x long=0x%lx
",k,i);
while(1)
;
}
创建一个新文件eswap.s51，输入以下汇编代码，并将它加入到项目endian中。这个汇编程序将我们的函数ltob()声明为PUBLIC，因此它能够由'C'程序调用。ltob()的第一个参数是指针，并通过DS80C400控制器的寄存器r3:r2:r1来传递。第二个参数也是一个指针，由IAR编译器压入偏移3至5堆栈(偏移3含有最低有效字节，偏移5含有最高有效字节)。首先，函数重新找到堆栈中存储的指针(指向一个32位值)，交换它所指向的值，将交换后的字节存储在相同位置。同样，16位值也被字节交换并存储在交换前的同一位置。注意，通过汇编函数来保留寄存器r6和r7。这是因为IAR编译器将这些寄存器视为永久寄存器，意味着任何函数调用都不应修改这些寄存器。
#include "reg400.inc"
r0_b0 equ 0 ; Register bank 0 equates.
r1_b0 equ 1
r2_b0 equ 2
r3_b0 equ 3
r4_b0 equ 4
r5_b0 equ 5
r6_b0 equ 6
r7_b0 equ 7
PROGRAM ENDIAN_SWAP
PUBLIC ltob
RSEG FAR_CODE:CODE:NOROOT(0)
; ********************************************************************
;
; int ltob(unsigned int* shortptr, unsigned long* longptr)
;
; ********************************************************************
ltob:
// shortptr is in r3:r2:r1
// longptr is in stack at offset 5
; get the longptr stored in the stack
mov a,SP
clr c
subb a,#5
mov b,a
mov a,esp
anl a,#0x3
orl a,#0xDC ; extended stack is at 0xff dc00
subb a,#00 ; subtract 0x0005 to point to MSB of 2 nd argument
mov DPX,#0xFF
mov DPH,a
mov DPL,b
push r6_b0 ; save r6:r7 for the compiler
push r7_b0
movx a,@DPTR
mov r4,a ;store least significant byte of 'longptr' in r4
inc DPTR
movx a,@DPTR
mov r5,a ;store middle byte of 'longptr' in r5
inc DPTR
movx a,@DPTR
mov r6,a ;store most significant byte of 'longptr' in r6
mov a,r4_b0
orl a,r5_b0
orl a,r6_b0
jz ltob_err ; is (longptr == NULL)?
mov dpx,r6_b0 ; point to the memory where 'longptr' is pointing to
mov dph,r5_b0
mov dpl,r4_b0
pop r6_b0 ; restore r6:r7 for the compiler
pop r7_b0
push dpx
push dph
push dpl
movx a,@dptr ; get the long value (in r4:r3:r2:r1) from the memory
mov r4,a
inc dptr
movx a,@dptr
mov r5,a
inc dptr
movx a,@dptr
mov r6,a
inc dptr
movx a,@dptr
mov r7,a
inc dptr
pop dpl
pop dph
pop dpx
mov a,r7_b0 ; swap the long value bytes and store it in memory
movx @dptr,a
inc dptr
mov a,r6_b0
movx @dptr,a
inc dptr
mov a,r5_b0
movx @dptr,a
inc dptr
mov a,r4_b0
movx @dptr,a
mov a,r1_b0 ; is (shortptr == NULL)?
orl a,r2_b0
orl a,r3_b0
jz ltob_err
mov dpx,r3_b0 ; point to a memory where the 'shortptr' is pointing to
mov dph,r2_b0
mov dpl,r1_b0
push dpx
push dph
push dpl
movx a,@DPTR ; get the integer value from memory
mov r2,a
inc dptr
movx a,@dptr
mov r1,a
inc dptr
pop dpl
pop dph
pop dpx
mov a,r1_b0 ; swap the integer bytes
movx @dptr,a
inc dptr
mov a,r2_b0
movx @dptr,a ; bytes of an integer are swapped and stored in memory
mov r3,#00 ; return 'success'
mov r2,#00
sjmp ltob_exit
ltob_err:
mov r3,#00 ; return 'error'
mov r2,#01
ltob_exit:
ret
END ; end of assembly program
局限性以及开发问题
以下是使用6.11A版的IAR编译器时发现的局限性：
IAR编译器用堆栈存储本地变量。在DS80C400中，堆栈限制为1024字节。DS80C400库的默认堆栈交换为384字节(ROM_SAVESIZE) 。如果您的程序声明了多个堆栈变量，确保该限制也适当地变化。要改变默认任务的交换大小，使用Dallas Semiconductor的task_genesis(unsigned int savesize)库或rom400_task.h中定义的task_fork(unsigned char priority, unsigned int savesize)，并给savesize参数提供正确的值。
printf、sprintf等函数存在一些问题：只有选择了'lowest optimization level'函数才能正常工作。要选择优化等级，找到project→options→ICC8051，并选择Code标签中的'None'。
IAR printf, sprintf的默认库不能正常工作。要使它们正常工作，您的C程序应包含IAR提供的C文件(如#include
结论
Dallas Semiconductor为IAR编译器提供支持C程序访问DS80C400 ROM软件的函数。用C程序能够访问网栈、存储管理器、进程调度器以及DS80C400的其它许多函数。使用C语言的DS80C400微控制器开发者能够编写出更精简的应用程序，赋予系统足够的速度、能力和代码空间。Dallas Semiconductor正致力于将所有目前工作与Keil编译器的DS80C400库移植到IAR。请经常访问DS80C400 IAR库主页获得升级。
工商网监
评论