OLED电子时钟制方案

在前篇文章中，我们通过库函数驱动DS1302获取到时间数据并且通过串口输出，而串口只是方便调试，要制作电子时钟，我们需要使用显示模块，本篇结合OLED对时间数据进行展示。

实验材料

Uno R3开发板
配套USB数据线
公对母杜邦线
面包板及配套连接线
OLED显示屏
DS1302模块

实验步骤

1. 根据原理图搭建电路图。

在前篇基础上添加了OLED模块连接。DS1302模块的VCC和GND连接Uno开发板的3.3V和GND。DS1302模块的CLK、DAT、RST对应连接Uno开发板的4、3、2引脚。OLED的VCC和GND分别连接开发板的3.3V和GND，OLED的SDA、SCL分别连接开发板的A4、A5引脚。

实验原理图如下图所示：

实验原理图

2. 新建sketch，拷贝如下代码替换自动生成的代码并进行保存。

#include < DS1302.h >
#include < Wire.h >
#include < Adafruit_GFX.h >
#include < Adafruit_SSD1306.h >

#define OLED_RESET     4
Adafruit_SSD1306 oled(128, 64, &Wire, OLED_RESET);

DS1302 rtc(2, 3, 4); //对应DS1302的RST,DAT,CLK

int sec_temp;

void initRTCTime(void)//初始化RTC时钟
{
  rtc.writeProtect(false); //关闭写保护
  rtc.halt(false); //清除时钟停止标志
  Time t(2020, 4, 25, 21, 50, 50, 7); //新建时间对象 最后参数位星期数据，周日为1，周一为2以此类推
  rtc.time(t);//向DS1302设置时间数据
}

void updatTime()//打印时间数据
{
  Time tim = rtc.time(); //从DS1302获取时间数据
  char date[20];
  char timer[20];
  snprintf(date, sizeof(date), "%04d-%02d-%02d",
           tim.yr, tim.mon, tim.date);
  snprintf(timer, sizeof(timer), "%02d:%02d:%02d",
           tim.hr, tim.min, tim.sec);

  if (tim.sec != sec_temp) { //一秒刷新一次
    oled.clearDisplay();//清屏
    oled.setCursor(15, 2);//设置显示位置
    oled.println("--CLOCK--");
    oled.setCursor(4, 25);//设置显示位置
    oled.println(date);
    oled.setCursor(18, 50);//设置显示位置
    oled.println(timer);
    oled.display(); // 开显示
  }
  sec_temp = tim.sec;
}

void setup() {
  oled.begin(SSD1306_SWITCHCAPVCC, 0x3C);
  oled.setTextColor(WHITE);//开像素点发光
  oled.clearDisplay();//清屏
  oled.setTextSize(2); //设置字体大小

  //新模块上电需要设置一次当前时间，
  //下载完成后需屏蔽此函数再次下载，否则每次上电都会初始化时间数据
  //  initRTCTime();

}

void loop() {
  updatTime();
}